A first example: a 1st order equation with a polynomial inhomogeneity.

(1) Clear Maple's memory:

>

restart;

(2) Enter the differential equation:

>	diffeq:= diff(y(t),t)+2*y(t)=t^2+2*t;

(3) Enter your flexible guess at the solution, and plug it into the differential equation:

>	yGuess := a + b*t + c*t^2; need := eval(subs( y(t)=yGuess, diffeq ));

We need this last equation to be true for all values of t, and the only way to ensure this is by

(4) making like terms balance on the two sides of the equation.

To get the constant terms   to balance,   we need

>	eq1:= b + 2*a = 0;

To get the t terms to balance, we need

>	eq2:= 2*c + 2*b = 2;

To get the t^2 terms to balance, we need

>	eq3:= 2*c = 1;

(5) Now we can solve these 3 requirements for the 3 undetermined coefficients, a,b,c:

>	sol:= solve({eq1,eq2,eq3},{a,b,c});

and so our answer is

>	ySolution := subs( sol, yGuess );

(6) We can check our work by plugging the supposed solution into the differential equation:

>	eval( subs( y(t)=ySolution, diffeq ) );

The LHS does equal the RHS, so our solution is good.

Another example: a sinusoidally forced harmonic oscillator.

(1) Clear Maple's memory:

>

restart;

(2) Enter the differential equation:

>	diffeq:= diff(y(t),t,t)+3*diff(y(t),t)+2*y(t)=sin(3*t);

(3) Enter your guess at the solution (with undetermined coefficients), and plug it into the differential equation:

>	yGuess := a*sin(3*t) + b*cos(3*t); need := eval(subs( y(t)=yGuess, diffeq ));

(4) Equate like terms by doing the following substitutions:

>	eq1:=subs( sin(3*t)=0,cos(3*t)=1,need); eq2:=subs( sin(3*t)=1,cos(3*t)=0,need);

(5) Solve for a and b:

>	sol:=solve({eq1,eq2},{a,b}); ySolution:=subs(sol,yGuess);

(6) Finally, check that our solution really is a solution:

>	eval( subs( y(t)=ySolution, diffeq ) );

Yes, the LHS does equal the RHS, so our solution is good.

A trickier example.

(1) Clear Maple's memory:

>

restart;

>	diffeq:= diff(y(t),t,t)+4*y(t)=t^2*exp(-3*t)*sin(t);

>	yGuess := (a*t^2+b*t+c)*exp(-3*t)*cos(t)         + (d*t^2+e*t+f)*exp(-3*t)*sin(t); need := expand(eval(subs( y(t)=yGuess, diffeq )));

Do some substitution to facilitate picking off coefficients of like terms:

>	eq0:=subs(cos(t)=C,sin(t)=S,exp(t)=1,t^2=TT,need);

Now pick off coefficient of each kind of term:

>	eq1:=subs(C=1,S=0,TT=0,t=0,eq0);

>	eq2:=subs(C=0,S=1,TT=0,t=0,eq0);

>	eq3:=subs(C=0,S=0,TT=1,t=0,eq0);

>	eq4:=subs(C=0,S=0,TT=0,t=1,eq0);

>	eq5:=subs(C=1,S=0,TT=0,t=1,eq0);

>	eq6:=subs(C=0,S=1,TT=0,t=1,eq0);

>	eq7:=subs(C=1,S=0,TT=1,t=0,eq0);

>	eq8:=subs(C=0,S=1,TT=1,t=0,eq0);

There were 6 kinds of terms, giving us 6 (informative) equations in the 6 unknowns.

>	sol:=solve({eq1,eq2,eq5,eq6,eq7,eq8},{a,b,c,d,e,f}); ySolution:=subs(sol,yGuess);

Check the result:

>	eval( subs( y(t)=ySolution, diffeq ) );

That LHS hopefully simplifies to equal the RHS.

>	simplify( expand(eval( subs( y(t)=ySolution, diffeq ) )));

Yes, it does!  So our solution is good.